pkgs/jni/android/build.gradle

// The Android Gradle Plugin builds the native code with the Android NDK.

group 'com.github.dart_lang.jni'
version '1.0'

buildscript {
    ext.kotlin_version = '1.6.10'
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        // The Android Gradle Plugin knows how to build native code with the NDK.
        classpath 'com.android.tools.build:gradle:7.1.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

rootProject.allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

apply plugin: 'com.android.library'

android {
    // Keeping the classes from being removed by proguard.
    defaultConfig {
        consumerProguardFiles 'consumer-rules.pro'
    }
    buildTypes {
        release {
            minifyEnabled false
        }
    }

    // Condition for namespace compatibility in AGP 8
    if (project.android.hasProperty("namespace")) {
        namespace 'com.github.dart_lang.jni'
    }

    // Adding [PortContinuation] and [PortProxy] classes shared between Flutter and
    // Dart-standalone versions of package:jni.
    sourceSets {
        main {
            java {
                srcDirs '../java/src/main/java'
            }
        }
    }

    // Bumping the plugin compileSdkVersion requires all clients of this plugin
    // to bump the version in their app.
    compileSdkVersion 31

    // Bumping the plugin ndkVersion requires all clients of this plugin to bump
    // the version in their app and to download a newer version of the NDK.
    // Note(MaheshH) - Flutter seems to download minimum NDK of flutter when
    // below line is commented out.
    // How about leaving it?
    // ndkVersion "21.1.6352462"

    // Invoke the shared CMake build with the Android Gradle Plugin.
    externalNativeBuild {
        cmake {
            path "../src/CMakeLists.txt"

            // The default CMake version for the Android Gradle Plugin is 3.10.2.
            // https://developer.android.com/studio/projects/install-ndk#vanilla_cmake
            //
            // The Flutter tooling requires that developers have CMake 3.10 or later
            // installed. You should not increase this version, as doing so will cause
            // the plugin to fail to compile for some customers of the plugin.
            // version "3.10.2"
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    defaultConfig {
        minSdkVersion 16
    }
}